ambient Module -- ambient free module of a subquotient, or ambient ring

ambient Module -- ambient free module of a subquotient, or ambient ring

Synopsis:

Usage: F = ambient M

Function: ambient -- ambient free module of a subquotient, or ambient ring

Input:

M, an instance of class Module.

Output:

F, an instance of class Module: the ambient free module of M.

The ambient free module is the target of both the generator matrix of M and the relations matrix of M.

If M is the module M = (image(g) + image(h)) / image(h), where g : F <--- G and h : F <--- H are matrices between free modules, then the ambient module of M is F.

i1 : R = QQ[x_1 .. x_10];

i2 : N = coker vars R ++ coker vars R



o2 = cokernel | x_1 x_2 x_3 x_4 x_5 x_6 x_7 x_8 x_9 x_10 0   0   0   0   0   0   0   0   0   0    |

              | 0   0   0   0   0   0   0   0   0   0    x_1 x_2 x_3 x_4 x_5 x_6 x_7 x_8 x_9 x_10 |



                            2

o2 : R-module, quotient of R

i3 : f = N_{0} - N_{1}



o3 = | 1  |

     | -1 |



o3 : Matrix

f is a matrix from a free module of rank 1 to N.

i4 : M = image(f)



o4 = subquotient (| 1  |, | x_1 x_2 x_3 x_4 x_5 x_6 x_7 x_8 x_9 x_10 0   0   0   0   0   0   0   0   0   0    |)

                  | -1 |  | 0   0   0   0   0   0   0   0   0   0    x_1 x_2 x_3 x_4 x_5 x_6 x_7 x_8 x_9 x_10 |



                               2

o4 : R-module, subquotient of R

i5 : ambient M



      2

o5 = R



o5 : R-module, free

i6 : ambient M == target generators M



o6 = true

i7 : ambient M == target relations M



o7 = true

See also:

cover Module -- get the covering free module

super Module -- get the ambient module

generators Module -- matrix of generators

relations Module -- the defining relations

Code:

     -- ../../../Macaulay2/m2/modules.m2:419-422
     ambient Module := Module => M -> (
          if M.?generators then M.generators.target
          else if M.?relations then M.relations.target
          else M)