annihilator Module -- the annihilator ideal

annihilator Module -- the annihilator ideal

Synopsis:

Usage: I = annihilator M

Function: annihilator -- the annihilator ideal

Input:

M, an instance of class Module: a module, or an ideal or ring element

Output:

I, an instance of class Ideal: The annihilator, ann(M) = { f in R | fM = 0 } where R is the ring of M.

ann is a synonym for annihilator.

i1 : R = QQ[a..d];

i2 : J = monomialCurveIdeal(R,{1,3,4})



                        3      2     2    2    3    2

o2 = ideal (b*c - a*d, c  - b*d , a*c  - b d, b  - a c)



o2 : Ideal of R

i3 : M = Ext^2(R^1/J, R)



o3 = cokernel {-3} | c -d 0 a -b |

              {-3} | d 0  c b 0  |

              {-3} | 0 c  b 0 a  |



                            3

o3 : R-module, quotient of R

i4 : annihilator M



                        3      2     2    2    3    2

o4 = ideal (b*c - a*d, c  - b*d , a*c  - b d, b  - a c)



o4 : Ideal of R

For another example, we compute the annihilator of an element in a quotient ring

i5 : A = R/(a*b,a*c,a*d)



o5 = A



o5 : QuotientRing

i6 : ann(a)



o6 = ideal (d, c, b)



o6 : Ideal of A

Macaulay 2 uses two algorithms to compute annihilators. The default version is to compute the annihilator of each generator of the module M and to intersect these two by two. Each annihilator is done using a submodule quotient.

An alternate algorithm is to do one large submodule quotient. This version is implemented in the routine annihilator'.

See also:

Module : Module -- a binary operator

quotient(Module,Module) -- ideal or submodule quotient

Code:

     -- ../../../Macaulay2/m2/modules2.m2:550-555
     annihilator Module := Ideal => (M) -> (
          if M == 0 then ideal 1_(ring M)
          else (
               P := presentation M;
               F := target P;
               intersect apply(numgens F, i-> ideal modulo(matrix{F_i},P))))