map(Module,Module,ZZ) -- make a map

map(Module,Module,ZZ) -- make a map

Synopsis:

Function: map -- make a map

Input:

an instance of class Module.

an instance of class ZZ.

Output:

an instance of class Matrix.

Optional arguments :

map(..., Degree)

map(..., DegreeMap => ...)

map(M,N,k) -- construct a map from a module N to M which is provided by the integer k.

If k is 0, then the zero map is constructed. If k is 1, then M and N should have the same number and degrees of generators in the sense that the modules cover M and cover N are equal, and then the map which sends the i-th generator of N to the i-th generator of M is constructed (and it may not be well-defined). Otherwise, M and N should be equal, or at least have the same number of generators.

i1 : R = QQ[x,y];

i2 : M = image vars R



o2 = image | x y |



                             1

o2 : R-module, submodule of R

i3 : N = coker presentation M



o3 = cokernel {1} | -y |

              {1} | x  |



                            2

o3 : R-module, quotient of R

i4 : f = map(M,N,1)



o4 = {1} | 1 0 |

     {1} | 0 1 |



o4 : Matrix

i5 : isWellDefined f



o5 = true

i6 : isIsomorphism f



o6 = true

i7 : g = map(M,cover M,1)



o7 = {1} | 1 0 |

     {1} | 0 1 |



o7 : Matrix

i8 : isWellDefined g



o8 = true

i9 : isIsomorphism g



o9 = false

i10 : h = map(cover M,M,1)



o10 = {1} | 1 0 |

      {1} | 0 1 |



o10 : Matrix

i11 : isWellDefined h



o11 = false

See also:

map(Module,Module,RingElement) -- make a map

map -- make a map

matrix -- make a matrix