Ext(Module,Module) -- compute an Ext module

Ext(Module,Module) -- compute an Ext module

Synopsis:

Usage: H = Ext(M,N)

Operator: Ext -- compute an Ext module

Input:

M, an instance of class Module.

N, an instance of class Module.

Output:

H, an instance of class Module: the Ext module of M and N, as a bigraded module, with the modules Extⁱ(M,N) for all values of i appearing simultaneously.

The modules M and N should be graded (homogeneous) modules over the same ring.

The computation of the total Ext module is possible for modules over the ring R of a complete intersection, according the algorithm of Shamash-Eisenbud-Avramov-Buchweitz. The result is provided as a finitely presented module over a new ring with one additional variable of degree {-2,-d} for each equation of degree d defining R. The variables in this new ring have degree length 2, i.e., is bigraded, with the degree i part of Ext^n(M,N) appearing as the degree {-n,i} part of Ext(M,N). We illustrate this in the following example.

i1 : R = QQ[x,y]/(x^3,y^2);

i2 : N = cokernel matrix {{x^2, x*y}}



o2 = cokernel | x2 xy |



                            1

o2 : R-module, quotient of R

i3 : H = Ext(N,N);

i4 : ring H



o4 = QQ [$X , $X , x, y, Degrees => {{-2, -2}, {-2, -3}, {0, 1}, {0, 1}}]

           1    2



o4 : PolynomialRing

i5 : S = ring H;

i6 : H



o6 = cokernel {-2, -2} | 0 0 0 0 0 0 0 0 0  0  0  y x 0    0    0     0     |

              {-1, -1} | y 0 0 0 0 x 0 0 0  0  0  0 0 $X_1 0    0     0     |

              {-1, -1} | 0 0 0 y 0 0 0 x 0  0  0  0 0 0    $X_1 0     0     |

              {-1, -1} | 0 y 0 0 x 0 0 0 0  0  0  0 0 0    0    0     0     |

              {-1, -1} | 0 0 y 0 0 0 x 0 0  0  0  0 0 0    0    0     0     |

              {0, 0}   | 0 0 0 0 0 0 0 0 y2 xy x2 0 0 0    0    $X_1y $X_1x |



                            6

o6 : S-module, quotient of S

i7 : isHomogeneous H



o7 = true

i8 : rank source basis( {-2,-3}, H)



o8 = 1

i9 : rank source basis( {-3}, Ext^2(N,N) )



o9 = 1

The result of the computation is cached for future reference.

See also:

ScriptedFunctor -- the class of all scripted functors

Adjust -- adjust the multi-degree

Repair -- repair the multi-degree