gb(..., SyzygyLimit => ...) -- stop when this number of syzygies is obtained

gb(..., SyzygyLimit => ...) -- stop when this number of syzygies is obtained

SyzygyLimit -- keyword for an optional argument used with gb which specifies that the computation should stop after a certain number of syzygies have computed.

This option is relevant only if Syzygies => true has been specified.

i1 : R = ZZ/101[x,y,z,w]



o1 = R



o1 : PolynomialRing

i2 : I = ideal(x*y-z^2,y^2-w^2,w^4)



                   2   2    2   4

o2 = ideal (x*y - z , y  - w , w )



o2 : Ideal of R

i3 : gb(I,SyzygyLimit => 1, Syzygies => true)



o3 = | y2-w2 xy-z2 yz2-xw2 |



o3 : GroebnerBasis

i4 : syz oo



o4 = {2} | -y2+w2 |

     {2} | xy-z2  |

     {4} | 0      |



             3       1

o4 : Matrix R  <--- R

i5 : gb(I,SyzygyLimit => 2, Syzygies => true)



o5 = | y2-w2 xy-z2 yz2-xw2 z4-x2w2 w4 |



o5 : GroebnerBasis

i6 : syz oo



o6 = {2} | -y2+w2 -xy2+xw2 |

     {2} | xy-z2  x2y-xz2  |

     {4} | 0      0        |



             3       2

o6 : Matrix R  <--- R

i7 : gb(I,SyzygyLimit => infinity, Syzygies => true)



o7 = | y2-w2 xy-z2 yz2-xw2 z4-x2w2 w4 |



o7 : GroebnerBasis

i8 : syz oo



o8 = {2} | -y2+w2 -xy2+xw2 0     -w4   yw4     xyw4+z2w4 |

     {2} | xy-z2  x2y-xz2  -w4   0     -xw4    -x2w4     |

     {4} | 0      0        y2-w2 xy-z2 yz2-xw2 z4-x2w2   |



             3       6

o8 : Matrix R  <--- R

See also:

Default value: infinity -- infinity

Function: gb -- compute a Groebner basis

Option name: SyzygyLimit -- stop when this number of syzygies is obtained