minors(ZZ,Matrix) -- ideal generated by minors

minors(ZZ,Matrix) -- ideal generated by minors

Synopsis:

Usage: J = minors(p,m)

Function: minors -- ideal generated by minors

Input:

p, an instance of class ZZ: the size of minors to compute

m, an instance of class Matrix: a matrix between free modules

Output:

J, an instance of class Ideal: the ideal generated by the p by p minors of the matrix m.

Optional arguments :

minors(..., First => ...) -- set the first minor to compute

minors(..., Limit => ...) -- specify how many to compute

minors(..., Strategy => ...) -- choose between Bareiss and Cofactor algorithms

Minors are generated in the same order as that used by subsets(ZZ,ZZ).

i1 : R = ZZ[vars(0..11)];

i2 : M = genericMatrix(R,a,4,3)



o2 = | a e i |

     | b f j |

     | c g k |

     | d h l |



             4       3

o2 : Matrix R  <--- R

i3 : transpose generators minors(2,M)



o3 = {-2} | -be+af |

     {-2} | -ce+ag |

     {-2} | -cf+bg |

     {-2} | -de+ah |

     {-2} | -df+bh |

     {-2} | -dg+ch |

     {-2} | -bi+aj |

     {-2} | -ci+ak |

     {-2} | -cj+bk |

     {-2} | -di+al |

     {-2} | -dj+bl |

     {-2} | -dk+cl |

     {-2} | -fi+ej |

     {-2} | -gi+ek |

     {-2} | -gj+fk |

     {-2} | -hi+el |

     {-2} | -hj+fl |

     {-2} | -hk+gl |



             18       1

o3 : Matrix R   <--- R

i4 : subsets(4,2)



o4 = {{0, 1}, {0, 2}, {1, 2}, {0, 3}, {1, 3}, {2, 3}}



o4 : List

The order is {{0,1},{0,1}}, {{0,2},{0,1}}, {{1,2},{0,1}}, and so on.

If the minors(..., First => ...) option is not given, the minors are stashed in the matrix under the key m.cache#MinorsComputation{j}. The class of this stashed object is the internal class MinorsComputation.