In this example we use the package IntroToSymmetry.m to work out the point group of the 2D unsteady stream function equation, 

Ψxxt+Ψyyt+ΨyΨxxx+ΨyΨxyy-ΨxΨxxy-ΨxΨyyy-nu*Ψxxxx-2nu*Ψxxyy-nu*Ψyyyy=0. 

The kinematic viscosity, nu is a constant.

This function turns off messages warning of possible spelling errors.

Off[General::spell]

Clear all symbols in the current context.

ClearAll[Evaluate[Context[]<>"*"]]

First read in the package which is located in User Home Folder/Library/Mathematica/Applications/SymmetryAnalysis.

Needs["SymmetryAnalysis`IntroToSymmetry`"]

Enter the input equation as a string. Don't include the == 0 at the end.

streamfunctionequation=
"D[psi[x,y,t],x,x,t]+D[psi[x,y,t],y,y,t]+
D[psi[x,y,t],y]*D[psi[x,y,t],x,x,x]+
D[psi[x,y,t],y]*D[psi[x,y,t],x,y,y]-
D[psi[x,y,t],x]*D[psi[x,y,t],x,x,y]-
D[psi[x,y,t],x]*D[psi[x,y,t],y,y,y]-
nu*D[psi[x,y,t],x,x,x,x]-
2*nu*D[psi[x,y,t],x,x,y,y]-
nu*D[psi[x,y,t],y,y,y,y]";

The function psi is a solution of the equation and this constraint must be applied in the form of a rule to the invariance condition. Be careful to check signs.

rulesarray=
{"D[psi[x,y,t],x,x,t]->-D[psi[x,y,t],y,y,t]-
D[psi[x,y,t],y]*D[psi[x,y,t],x,x,x]-
D[psi[x,y,t],y]*D[psi[x,y,t],x,y,y]+
D[psi[x,y,t],x]*D[psi[x,y,t],x,x,y]+
D[psi[x,y,t],x]*D[psi[x,y,t],y,y,y]+
nu*D[psi[x,y,t],x,x,x,x]+
2*nu*D[psi[x,y,t],x,x,y,y]+
nu*D[psi[x,y,t],y,y,y,y]"};

Enter the list of independent variables.

independentvariables={"x","y","t"};

Enter the list of dependent variables.

dependentvariables={"psi"};

Enter the list of function and/or constant names that must be preserved when the equation is converted to generic variables.

frozennames={"nu"};

Enter the maximum derivative order of the equation set.

p=4;

The maximum derivative order that the infinitesimals are assumed to depend on is specified by the input parameter r. This parameter is only nonzero when the user is looking for Lie contact groups or Lie-Backlund groups. For the usual case where one is searching for point groups set r=0.

r=0;

When searching for Lie-Backlund groups (r=1 or greater) one can, without loss of generality, leave the independent variables untransformed. The corresponding infinitesimals (the xse's) are set to zero by setting xseon=0. If one is searching for point groups then set xseon=1. The choice xseon=1 is also an option when looking for Lie-Backlund groups and this can be useful when looking for contact symmetries.

xseon=1;

When searching for Lie-Backlund groups it is necessary to differentiate the input equation with respect to all independent variables producing derivatives of order p+r. These higher order differential consequences are appended to the set of rules applied to the invariance condition. This process is carried out automatically when internalrules=1. For point groups the equation or equation system is the only rule or set of rules needed and one sets internalrules=0.

internalrules=0;

Now work out the determining equations of the Lie point group that leaves the equation invariant. The output is available as a table of strings called zdeterminingequations. The Mathematica function Timing outputs the time required for FindDeterminingEquations to execute.

Timing[FindDeterminingEquations[
independentvariables,dependentvariables,frozennames,p,r,xseon,streamfunctionequation,rulesarray,internalrules]]

Let's look at the partial derivatives that appear in the invariance condition.

invarconditiontable

Here are the determining equations in terms of z-variables.

zdeterminingequations;

Length[zdeterminingequations]

Here is the correspondence between z-variables and conventional variables.

ztableofrules

Now solve the determining equations in terms of multivariable polynomials. The Mathematica function Solve uses Gaussian elimination to solve a 
large number of linear equations for the polynomial coefficients. The time roughly follows

time/timeref=((number of equations)/(number of equationsref))^n

where the exponent is between 2.4 and 2.7. The Mathematica function Timing outputs the time required for the SolveDeterminingEquations function to execute.

Timing[SolveDeterminingEquations[independentvariables,dependentvariables,r,xseon,
zdeterminingequations,order=4]]

Here are the infinitesimal transformation functions for the independent variables.

xsefunctions

and for the dependent variables.

etafunctions

infinitesimalgroupsxy=infinitesimalgroups/.{z1->x,z2->y,z3->t,z4->psi};

Check the groups; xse's are on the left, eta's are on the right.

Column[infinitesimalgroupsxy]

Check the infinitesimals in the determining equations.

Simplify[ToExpression[zdeterminingequations]]

Note the increasing powers of time that are evidence of arbitrary time dependent translations of the spatial coordinates. In addition there is an arbitrary function of time that can be added as a translation of the stream function. Lets remove these three arbitrary functions of time and then form the commutator table of the remaining groups.

infinitesimalgroupsxpsi=Drop[infinitesimalgroupsxy,{8,19}]

Column[infinitesimalgroupsxpsi]

Note the invariance under coordinate rotation and under transformation to a system of coordinates rotating at a constant angular frequency. In addition the equations admits a one parameter space-time dilation group.

Construct the commutator table.

MakeCommutatorTable[independentvariables,dependentvariables,infinitesimalgroupsxpsi]

MatrixForm[commutatortable]

MaxMemoryUsed[ ]